Public Class CredentialProfileGetter


    'GetCredentialProfile gets a CredentialProfile for the specified userID.
    'GetCredentialProfile first checks to see if a CredentialProfile already exists
    'for the specified user. If so, it uses the password to obtain access to the profile
    'for the calling user.
    'If no profile exists, GetCredentialProfile creates one.
    Public Shared Function GetCredentialProfile(ByVal connection As Scheduler, ByVal userID As String, ByVal password As String) As CredentialProfile
        Dim filter As New CredentialProfileFilter(userID)
        Dim profile As CredentialProfile
        Dim objects As IADTObjects
        Dim recordCount As Int32

        objects = connection.GetObjectsWhere(filter, 0, True, recordCount)
        'there should be at most one returned
        If objects.Count > 0 Then
            profile = CType(objects(0), CredentialProfile)

            'VerifyPassword confirms that the correct password
            'has been specified, and grants the caller permission to use
            'the profile.
            If profile.VerifyPassword(password, True) Then
                'All set.
                Return profile
            Else
                'The password is incorrect
                Throw New Exception("Incorrect password specified")
                Return Nothing
            End If
        End If

        'else there is no existing CredentialProfile for the specified userID.
        'Create a new one.

        profile = CType(connection.CreateObject(ClassIDEnum.CID_CredentialProfile), CredentialProfile)
        profile.UserID = userID
        profile.SetPassword(password)
        profile.Save()
        Return profile

    End Function


    'Use in a call to IScheduler.GetObjectsWhere to get the job with the specified name.
    Private Class CredentialProfileFilter
        Implements IObjectRequestFilter
        Public UserID As String = ""
        Public Sub New(Optional ByVal name As String = "")
            UserID = name
        End Sub
        Public Function GetOrderClause() As String Implements ArcanaDevelopment.adTempus.Client.IObjectRequestFilter.GetOrderClause
            Return ""
        End Function

        Public Function GetSelectClause() As String Implements ArcanaDevelopment.adTempus.Client.IObjectRequestFilter.GetSelectClause
            Return "*"
        End Function

        Public Function GetTableName() As String Implements ArcanaDevelopment.adTempus.Client.IObjectRequestFilter.GetTableName
            Return "credentialProfile"
        End Function

        Public Function GetWhereClause() As String Implements ArcanaDevelopment.adTempus.Client.IObjectRequestFilter.GetWhereClause
            'This filter only looks at Windows logon credentials, which
            'do not have the credentialType set.
            Return "userID='" & UserID & "' and credentialType is NULL"
        End Function
    End Class

End Class